使用ASPjpeg组件创建缩略图

'==================================================
'函数名：CreateSmallPicture
'作  用：创建缩略图（缩略图大小为w:150,h:按比例缩小)
'参  数：strPath 源文件名
'==================================================
Function CreateSmallPicture(strPath)
 Dim objJpeg
 Set objJpeg = Server.CreateObject("Persits.Jpeg")
 objJpeg.Open Server.MapPath(strPath) 
 objJpeg.Width = 150
 objJpeg.Height =150/objJpeg.OriginalWidth*objJpeg.OriginalHeight
 objJpeg.Save Server.MapPath(CreateSmallPath(strPath))
 Set objJpeg=Nothing
End Function
'==================================================
'函数名：CreateSmallPath
'作  用：创建缩略图的路径（在原文件名前加“s_”)
'参  数：strPath 源文件名
'==================================================
Function CreateSmallPath(strPath)
 Dim strFileName,i,arrFileName,strSmallPath
 arrFileName=Split(strPath,"/")
 For i=0 to Ubound(arrFileName)-1
  strSmallPath=strSmallPath&arrFileName(i)&"/"
 Next
 strFileName="s_"&arrFileName(Ubound(arrFileName))
 CreateSmallPath=strSmallPath&strFileName
End Function

sub BuildSmallPic(PicUrl)
'PicUrl是图片在服务器上的绝对路径
Set Jpeg = Server.CreateObject("Persits.Jpeg")    '创建实例
Jpeg.Open PicUrl
if Jpeg.OriginalWidth>110 then
Jpeg.Width = 110
Jpeg.Height = (Jpeg.Originalheight/Jpeg.OriginalWidth)*110
else
Jpeg.Width = Jpeg.OriginalWidth
Jpeg.Height = Jpeg.Originalheight
end if
PicPath=left(PicUrl,instrrev(PicUrl,"\"))
Picname=mid(PicUrl,instrrev(PicUrl,"\")+1)
Jpeg.Save PicPath&"small"&Picname
Jpeg.Close:
Set Jpeg = Nothing
end sub